Отчет о проделанной работе. 4 Создание классов 5 Класс «Компания»

Скачать 494.07 Kb.

Название	Отчет о проделанной работе. 4 Создание классов 5 Класс «Компания»
страница	2/4
Дата публикации	13.03.2015
Размер	494.07 Kb.
Тип	Отчет

100-bal.ru > Информатика > Отчет

1 2 3 4

Цель разработки

Разработать систему классов , которая дает обзор:

основных типов классов
основных типов данных (для атрибутов классов)
основных связей между объектами

Разработать пример создания классов с помощью мастера
Разработать пример работы с Cache` Портал, Cache` Terminal, Cache` Studio
Разработать пример работы с БД Cashe при помощи прямого доступа к глобалам, объектного подхода и реляционного представления, SQL-запросов

Отчет о проделанной работе.

В ходе работы были на примере объектной СУБД Cache` были изучены методы работы с данными, которые используют объектный подход, реляционное представление и низкоуровневый доступ к внутренним структурам. Так же были рассмотрены элементы Cashe куба, необходимые для разработки БД(Cache` Studio), ее администрирования(Cache` Портал) и отладки различных функций и процедур(Cache` Terminal). Итогом разработки являются разработанная система классов, программы, написанные в среде Cache` Studio и примеры, демонстрирующие работу с Cache` Портал.

Создание классов

Определим в среде Cache` Studio четыре класса:

Класс "Компания" - хранимый класс. Содержит свойства:

название - строковое (обязательное, уникальное),
адрес - встроенный объект класса "Адрес",
сферы деятельности - массив или список строковых значений.
Метод класса - Создать - создает и сохраняет в базе данных новый объект класса "Компания" (и встроенный в него объект класса "Адрес").
Входные параметры: название компании, город, улица, номера.
Выходной параметр: ссылка на созданный объект.

Класс "Адрес" - встроенный. Содержит свойства:

город - строковое,
улица - строковое,
номера - строковое в формате дом-корпус-квартира.
Метод экземпляра - "Полный адрес" - возвращает строку, содержащую название города и улицы в предопределенном формате
(например, "г.Москва, 2-я Бауманская, 5").

Класс "Сотрудник" - хранимый. Содержит свойства:

имя - строковое (обязательное),
компания - ссылка на объект класса "Компания" (обязательное),
должность - строковое,
Метод экземпляра - "Информация о сотруднике" - возвращает строку, содержащую имя сотрудника, название компании, где он работает, и его должность.

Класс "Руководитель" - производный от класса "Сотрудник". Содержит свойства:

дата назначения - дата и время (обязательное),
Переопределенный метод экземпляра - "Информация о сотруднике" - возвращает строку, содержащую имя, название компании и сведения, с какого времени он является руководителем компании.

Для создания классов используется среда Cache` Studio.

Для определения методов и запросов классов используются соответствующие мастера.

Для просмотра созданных классов используется среда Cache` Портал (раздел Classes, пакет USER) .

Класс «Компания»

Создание класса "Компания" с помощью мастера

Чтобы создать класс необходимо запустить Studio. Для этого щелкаем на куб Cache (на панели задач) и из меню выбираем "Студия". Здесь можно создавать классы, их свойства, методы:

Создание нового класса поддерживается мастером. Щелкните правой кнопкой мыши по значку "Классы" в окне "Рабочая поверхность", выберите в контекстном меню "Создание Класс":

На экране появится "Мастер создания класса". Определение нового класса начинается с задания его имени и описания. Создадим класс "Компания", который является хранимым классом:

Имя класса - Organization, сопровождается его кратким описанием (пакет User используется по умолчанию, его можно не менять). Если затем Вы щелкните по "Далее", то попадете на следующий экран, где устанавливается тип класса. На данной форме, в соответствии с нашим условием, мы устанавливаем тип класса Persistent (Хранимый):

Результат, полученный при создании класса, можно просмотреть в окне, демонстрирующим иерархию классов:

Определение свойств класса "Компания"

Для того, чтобы определить свойства класса необходимо в меню выбрать пункты Класс

Добавить

Новое свойство:

Или на панели инструментов выбрать значок

. Откроется окно определения нового свойства:

Задаем свойство компании - Название (Name). Далее выбираем тип свойства. Т.к. название компании имеет строковый тип, то из списка, который появляется после нажатия на кнопку "Просмотр", выбираем String:

Нажимаем кнопку ОК:

По условию работы данное свойство является обязательным и уникальным:

Далее нажимаем кнопку "Готово". Свойство создано.

Создаем свойство компании "адрес":

Свойство компании "адрес" является встроенным объектом класса "Адрес":

Нажимаем кнопку ОК:

Далее определяем свойство "Сферы деятельности":

Свойство "Сферы деятельности" представляет собой массив или список строковых значений:

Создание метода класса с помощью мастера

Чтобы определить новый метод, необходимо нажать кнопку

на панели инструментов либо выбрать следующие пункты меню: Класс

Добавить

Новый метод. Откроется мастер создания метода. Определяем название нового метода:

Далее определяем список аргументов и их тип:

Выбираем выходное значение. Нажимаем на кнопку "Просмотр" и выбираем из открывающего списка тип возврата:

Список аргументов и выходное значение:

Далее в теле метода создаем новый экземпляр класса Organization и определяем входные аргументы, сохраняем экземпляр. В итоге, получаем:

ClassMethod CreateOrganization(OrganizationName As %String, City As %String, Street As %String, Number As %String) As Organization{
set NewOrganization = ##Class(User.Organization).%New()
set NewOrganization.OrganizationAddress = ##Class(User.Address).%New()
set NewOrganization.Name = OrganizationName
set NewOrganization.OrganizationAddress.City = City
set NewOrganization.OrganizationAddress.Street = Street
set NewOrganization.OrganizationAddress.HomeNumber = Number
do NewOrganization.%Save()
Quit NewOrganization
}

Компиляция класса

После создания класса, его свойств и методов класс необходимо откомпилировать. Использование классов возможно только после их компиляции. При этом может быть задано, подлежит ли компиляции один - единственный, все измененные или же вообще все классы. Если компилируется только один класс, компилятор сначала проверяет, модифицировался ли родительский класс этого класса с момента его последней компиляции (или, возможно, он еще ни разу не компилировался). Таким образом, автоматически компилируются все измененные классы, от которых был произведен компилируемый класс. Чтобы откомпилировать класс, необходимо нажать кнопку

на панели инструментов.

Листинг (класс "Компания"):

// ------ класс является хранимым, т.е. наследует возможности от системного класса %Library.Persistent

Class User.Organization Extends %Persistent
{

//------ свойство класса "Название" является строкой. Оно обязательно и уникально;
Property Name As %String [ Required ];
Index NameIndex On Name [ Unique ];

//------- свойство Адрес как встроенный объект класса Address;
Property OrganizationAddress As Address;

//------ свойство Сферы деятельности как список строковых значений;
Property Business As list Of %String;

//-----метод класса.
//------ Аргументы метода : OrganizationName - строковый тип, City - строковый тип, Street -
строковый тип, Number - строковый тип.
//----- Метод возвращает ссылку на экземпляр объекта;

ClassMethod CreateOrganization(OrganizationName As %String, City As %String, Street As %String, Number As %String) As Organization
{
//-----Создаем новый экземпляр класса Organization в памяти процесса.
//------ Локальная переменная NewOrganization содержит объектную ссылку на новый экземпляр (на созданный объект).

set NewOrganization = ##Class(User.Organization).%New()

//-----аналогично создаем встроенный объект класса "Адрес".
set NewOrganization.OrganizationAddress = ##Class(User.Address).%New()

//-----устанавливаем свойства объектов на основе входных аргументов.

set NewOrganization.Name = OrganizationName
set NewOrganization.OrganizationAddress.City = City
set NewOrganization.OrganizationAddress.Street  = Street
set NewOrganization.OrganizationAddress.HomeNumber = Number

//-------Сохраняем новый экземпляр в базе данных.

do NewOrganization.%Save()

//----- Завершаем процедуру и возвращаем ссылку на созданный объект

Quit NewOrganization
}

}

Класс «Адрес»

Создание класса "Адрес"

Класс является встроенным и содержит следующие свойства:

город - строковое;
улица - строковое;
номера - в формате дом-корпус-квартира;

Метод экземпляра – «Полный адрес» - возвращает строку, содержащую название города и улицы в предопределенном формате (например, «г.Москва, 2-я Бауманская, 5»).

С помощью мастера создадим класс "Адрес":

Класс является встроенным:

Далее нажимаем кнопку "Готово".

Определение свойств класса "Адрес".Определим свойство "Город":

Данное свойство является строкой:

Нажимаем кнопку "Готово".

Аналогичным образом определяется свойство "Улица".

Теперь определим свойство "Номера", тип которого является строка в формате дом-корпус-квартира:

Укажем тип свойства как строковое:

Далее прописываем шаблон:

Нажимаем кнопку "Готово".

Метод класса "Адрес". Вызываем мастер создания метода.

Выбираем тип возвращаемого значения.

Метод не имеет аргументов, поэтому нажимаем кнопку "Готово". Далее прописываем тело метода. Компилируем класс.

Листинг (класс "Адрес"):

// имя класса - Address. % SerialObject-системный супер-класс. От него образуются встраиваемые классы

Class User.Address Extends %SerialObject [ ClassType = serial ]
{
// свойство City имеет строковый тип
Property City As %String;

// свойство Street имеет строковый тип
Property Street As %String;

// Это свойство, содержащее значение. Это свойство типов данных. Данный класс типов данных поддерживает параметр PATTERN. PATTERN — задает шаблон, которому должна соответствовать строка ".N1""-"".N1""-"".N"
Property HomeNumber As %String(PATTERN = ".N1""-"".N1""-"".N");

//метод экземпляра. Возвращает строку в формате город- улица-дом
Method FullAddress() As %String
{
//this - ссылка на экземпляр объекта. This используется только в методе экземпляра. В методе класса она отсутствует
Quit "г." _ ##this.City _ ", ул." _ ##this.Street _ ", " _ ##this.HomeNumber
}
}

Класс «Сотрудник»

Создание класса "Сотрудник"

Данный класс является хранимым и содержит следующие свойства:

имя – строковое (обязательное);
компания — ссылка на объект класса «Компания» (обязательное);
должность – строковое.

Метод экземпляра – «Информация о сотруднике» - возвращает строку, содержащую имя сотрудника, название компании, где он работает и его должность. Создадим новый класс:

Тип данного класса - хранимый:

Определение свойств класса "Сотрудник". Определим свойство "Имя":

Оно является строковым и обязательным:

Укажем тип свойства:

Нажимаем кнопку "Готово".

Далее определим свойство "Компания". Оно является ссылкой на объект класса «Компания». Данное свойство обязательно:

Свойство класса "Должность" определяется аналогично свойству "Имя". Оно также является строковым, но не является обязательным.

Метод класса "Сотрудник". Запускаем мастер создания метода. Определяем название метода, тип его выходных параметров:

Укажем тип выходного значения как строковое:

Далее прописываем тело метода и компилируем класс.

Листинг (класс "Сотрудник"):

// класс является хранимым, т.е. наследует возможности от системного класса % Library.Persistent

Class User.Worker Extends %Persistent
{

//свойство WorkerName имеет строковый тип и является обязательным
Property WorkerName As %String [ Required ];

// свойство WorkerOrganization является ссылкой на объект класса "Компания". Свойство обязательное
Property WorkerOrganization As Organization [ Required ];

// свойство WorkerPost имеет строковый тип
Property WorkerPost As %String;

// Метод экземпляра. Возвращает строку, содержащую имя сотрудника, название компании, где он работает, и его должность.
Method WorkerInfo() As %String
{
// this - ссылка на экземпляр объекта.

Quit "Имя работника: " _ ##this.WorkerName _", компания: " _ ##this.WorkerOrganization.Name _ ", должность: " _ ##this.WorkerPost
}

}

Класс Руководитель

Создание класса "Руководитель"

Класс "Руководитель" является производным от класса «Сотрудник». Содержит свойства:

дата назначения – дата и время (обязательное),

Переопределенный метод экземпляра – «Информация о сотруднике» - возвращает строку, содержащую имя, название компании и сведения, с какого времени он является руководителем компании.

Вызываем мастер создания класса:

Далее выбираем базовый класс - класс Worker:

Далее определяем свойства и методы класса аналогично предыдущим пунктам.

Затем определяем тело метода и компилируем класс.

Листинг (класс "Руководитель"):

// класс Manager является производным от класса «Сотрудник». Manager - хранимый класс

Class User.Manager Extends User.Worker [ ClassType = persistent ]
{
//свойство HireDate имеет тип %TimeStamp отметка - времени, состоящая из даты и времени TIMESTAMP
Property HireDate As %TimeStamp [ Required ];

// Переопределенный метод экземпляра – «Информация о сотруднике» - возвращает строку, содержащую имя, название компании и сведения, с какого времени он является руководителем компании
Method WorkerInfo() As %String
{
Quit ##this.WorkerName _" - " _ ##this.WorkerOrganization.Name _ ", руководитель с " _ ##this.HireDate
}

}

Создание объектов

Приведем пример программы на языке Cache` Object Script в среде Cache` Studio и вызов ее из среды Cache` Terminal. Программа выполняет следующие действия:

Пункт 1. Отображать запрос на ввод и ввести с консоли имя сотрудника, название компании и должность.
Пункт 2. Создать новый объект класса "Руководитель", если должность "руководитель" или объект класса "Сотрудник" в противном случае. Определить поля объекта: имя и должность.
Пункт 3. Используя запрос SQL, получить ссылку на компанию с указанным названием и присвоить эту ссылку полю компания.
Пункт 4. Если компании с указанным названием не существует, то ввести с консоли по запросу город, улицу и номера, создать новый объект класса компания, вызвав соответствующий метод класса. Присвоить ссылку на компанию объекту сотрудника из п.2.
Пункт 5. Сохранить новый объект "Сотрудник" (или "Руководитель") в базе данных.

Ввод выполняется в цикле. Признак завершения цикла - ввод специального символа (например, пустой строки).

Исходные данные

Созданные классы:

Класс "Адрес" (листинг)
Класс "Компания" (листинг)
Класс "Сотрудник" (листинг)
Класс "Руководитель" (листинг)

Справка

При выполнения были изучены основы языка Cache` Object Script и использованы следующие команды и операторы:

для ввода данных команду read,
для вывода - write,
для присвоения значения переменной - set,
для вызова процедуры - do,
для организации циклов - for или while,
для задания условия блок - if { } else { },
для выходя из процедуры - quit,
для конкатенации - оператор "_".

Для создания процедур можно использовать встроенные методы:

%New() - создать объект,
%Save() - сохранить объект в базе,
%OpenId() - открыть объект, хранящийся в базе, по его идентификатору,
%DeleteId() - удалить объект из базы данных,
SetAt() - сохранить значение элемента массива,
GetAt() - извлечь значение элемента массива.

Для обращения к базе данных можно использовать класс %ResultSet и его методы:

Prepare() - подготовить запрос,
Execute() - выполнить запрос,
Next() - извлечь строку из результата запроса,
Data() - получить значение поля в текущей строке.

Для работы с глобалами можно использовать функции:

$Get - получить значение глобала,
$Order - получить очередной в последовательности глобал,
$Data - проверить существование глобала.

Запуск Cache` Studio

Cache` Studio - это интегрированная, визуальная среда создания объектно-ориентированных баз данных и Web-приложений. Она имеет следующие особенности для обеспечения быстрой разработки:

Возможность редактирования определений классов, CSP-страниц, программ на Cach` Object Script(COS) в единой интегрированной среде;
Полнотекстовое редактирование с подсветкой команд, а также проверкой синтаксиса на следующих языках: Cach` Object Script, Basic, Java, SQL, JavaScript, HTML, и XML;
Поддержка команды разработчиков, работающих с общим репозиторием кода приложения;
Наличие отладчика;
Организация кода в проект;
Наличие мастеров, позволяющих создавать классы, методы, свойства, связи, WEB-формы.

Исходный код приложения Cache` оформляется в виде проекта. Проект может содержать следующие компоненты: классы, программы, CSP-файлы. Можно создавать новые проекты, открывать и изменять существующие. Также существует возможность добавления или удаления компонентов из проекта.

Для запуска "Студии" необходимо на панели задач нажать правой кнопкой мыши на значок Cache`

и в выпадающем меню выбрать "Студия":

После запуска Студии появится окно, содержащее несколько закладок. Внешний вид среды разработки Cach` Studio:

Создание программы в среде Cache` Studio

Создаем в среде Cache` Studio файл программы, который имеет расширение MAC. Для этого необходимо справа на "рабочей поверхности" правым щелчком мыши на пункте "Программы" вызвать меню и выбрать в нем пункт "Создание Программа":

Результат можно увидеть ниже:

Сохраняем программу с именем, которое необходимо: "Файл" > "Сохранить как…"

Теперь мы можем на языке Cache` Object Script писать программу. Рассмотрим подробно действия, которые должна выполнять программа.

Пункт 1

Пример: Отобразить запрос на ввод и ввести с консоли имя сотрудника, название компании и должность.

Код программы выглядит так:

write !,"Завершение ввода происходит по двойному нажанию на 'Enter' ",!
for
{
read !,"Введите имя сотрудника: ",Name
quit:Name=""
read !,"Введите название компании: ",CompanyName
quit:CompanyName=""
read !,"Введите должность: ",Post
quit:Post=""
}

Команда write выведет сообщение на экран монитора. Восклицательный знак выполняет переход на новую строку. Далее организован цикл с помощью безаргументной формы команды for, в которой нет ни переменной цикла, ни начального, ни конечного значения. Команда read выдаст подсказку пользователю о том, что необходимо ввести, и введет ответы пользователя в переменные Name, CompanyName, Post. Далее идет постусловная конструкция вида: quit:<условие>. Команда quit выполнится, если истинно условие.

Пункт 2

Пример: Создим новый объект класса "Руководитель", если должность "руководитель" или объект класса "Сотрудник" в противном случае. Определить поля объекта: имя и должность.

Основной синтаксис для создания новых экземпляров объектов - это использование метода класса %New:

set oref = ##Class(ClassName).%New()

, где oref - ссылка OREF на новый объект, ClassName - это имя класса, чувствительно к регистру букв и может содержать имя пакета, ##Class() - это макровызов, который используется для вызова методов класса.

В нашем случае необходимо создать объект класса "Руководитель", если должность "руководитель". Для этого используется конструкция if:

if (Post="руководитель"){code} else {code}

В блоке кода создается новый объект:

set NewWM = ##Class(User.Manager).%New()

Далее идет строка, необходимая для указания даты и время назначения сотрудника, если он является руководителем. Используется системная переменная $Horolog, которая содержит текущее время в виде пары чисел: первое число задает внутренний формат даты, второе число задает количество секунд, прошедших с полуночи. Второй аргумент функции $ZDateTime - это формат возвращаемой даты.

Создание объекта класса "Сотрудник" в блоке кода else:

set NewWM = ##Class(User.Worker).%New()

Полностью эта часть кода выглядит так:

if (Post="руководитель")
{
set NewWM = ##Class(User.Manager).%New()
set NewWM.HireDate = $ZDateTime($Horolog,3)
}
else
{
set NewWM = ##Class(User.Worker).%New()
}
set NewWM.WorkerName = Name //определение поля имя
set NewWM.WorkerPost = Post //определение поля должность

Пункт 3

Пример: Используя запрос SQL, получим ссылку на компанию с указанным названием и присвоим эту ссылку полю компания.

Используем объект класса %ResultSet для подготовки динамического SQL-запроса:

set rset = ##class(%ResultSet).%New("%DynamicQuery:SQL")
Do rset.Prepare("SELECT ID FROM SQLUser.Organization WHERE Name = '"_CompanyName_"'")
Do rset.Execute() //выполнение запроса

Метод Prepare - подготавливает (компилирует) запрос для выполнения, метод Execute - выполняет запрос.

Присвоение ссылки идет в теле конструкции if в блоке кода else:

set CompanyID = rset.Data("ID")
set Company = ##class(User.Organization).%OpenId(CompanyID)

Пункт 4

Пример: Если компании с указанным названием не существует, то введем с консоли по запросу город, улицу и номера, создать новый объект класса компания, вызвав соответствующий метод класса .Присвоим ссылку на компанию объекту сотрудника из п.2.

Код этой части программы выглядит следующим образом:

if 'rset.Next() //проверяем, имеет ли набор данные
{
read !,"Введите город, где расположена компания: ",City
read !,"Введите название улицы, где расположена компания: ",Street
do
{
read !,"Введите дом-корпус-квартиру, где расположена компания: ",Numberz
}
while ('(Numberz ?.N1"-".N1"-".N))

set Company = ##class(User.Organization).CreateOrganization(CompanyName,City,Street,Numberz)
}
else
{
set CompanyID = rset.Data("ID")
set Company = ##class(User.Organization).%OpenId(CompanyID)
}
set NewWM.WorkerOrganization = Company
do NewWM.%Save()

Рассмотрим пояснения к тексту программы. Конструкция вида:

do
{
read !,"Введите дом-корпус-квартиру, где расположена компания: ",Numberz
}
while ('(Numberz ?.N1"-".N1"-".N))

означает, что ввод производится до тех пор, пока введенные данные не будут соответствовать шаблону ("?" - оператор соответствия шаблону).

Создаем новый объект класса "компания", вызвав соответствующий метод класса:

set Company = ##class(User.Organization).CreateOrganization(CompanyName,City,Street,Numberz)

Пояснение блока кода else смотрите выше в п.3. Присваиваем ссылку на компанию объекту сотрудника из п.2:

set NewWM.WorkerOrganization = Company

Пункт 5

Пример: Сохранить новый объект "Сотрудник" (или "Руководитель") в базе данных.

Для этого используется конструкция:

do NewWM.%Save()

Объединим все части и посмотрим листинг этой программы полностью.

Листинг программы

write !,"Завершение ввода происходит по двойному нажанию на 'Enter' ",!
for
{
read !,"Введите имя сотрудника: ",Name
quit:Name=""
read !,"Введите название компании: ",CompanyName
quit:CompanyName=""
read !,"Введите должность: ",Post
quit:Post=""

if (Post="руководитель")
{
    set NewWM = ##Class(User.Manager).%New()
    set NewWM.HireDate = $ZDateTime($Horolog,3)
}
else
{
    set NewWM = ##Class(User.Worker).%New()
}
set NewWM.WorkerName = Name
set NewWM.WorkerPost = Post
set rset = ##class(%ResultSet).%New("%DynamicQuery:SQL")
Do rset.Prepare("SELECT ID FROM SQLUser.Organization WHERE Name = '"_CompanyName_"'")
Do rset.Execute()
if 'rset.Next()
{
    read !,"Введите город, где расположена компания: ",City
    read !,"Введите название улицы, где расположена компания: ",Street
    do
    {
       read !,"Введите дом-корпус-квартиру, где расположена компания: ",Numberz
    }
    while ('(Numberz ?.N1"-".N1"-".N))
     set Company = ##class(User.Organization).CreateOrganization(CompanyName,City,Street,Numberz)
}
else
{
    set CompanyID = rset.Data("ID")
    set Company = ##class(User.Organization).%OpenId(CompanyID)
  }
set NewWM.WorkerOrganization = Company
do NewWM.%Save()
}

Теперь в среде Cache` Terminal посмотрим, как эта программа работает.

Запуск программы в в среде Cache` Terminal

Утилита Cache` Terminal может быть использована для отладки программ, процедур, функций, проверки работы отдельных операторов. Работа ведется в режиме командной строки. Утилита чрезвычайно проста. После приглашения набирается команда и нажимается ENTER. Здесь же выводится результат выполнения команды. Окно утилиты приведено ниже.

Для запуска Терминала необходимо на панели задач нажать правой кнопкой мыши на значок Cache`

и в выпадающем меню выбрать "Терминал":

Откроется окно утилиты, которое содержит командную строку для ввода команд и отображения результатов их выполнения. Вызов программы осуществляется с помощью команды do. После набора команды и ее параметров следует нажать Enter. В окне отобразится результат выполнения команды. Рассмотрим пример вызова созданной программы:

Вид программы после запуска, запрос ввода данных:

Ввод сотрудника, должность которого НЕ руководитель. Как видно из рисунка, что ввод продолжается циклически:

Ввод сотрудника, должность которого руководитель, а компания, в которой он работает, еще не введена в БД:

Работа с Порталом

Для запуска "Портала" необходимо на панели задач нажать правой кнопкой мыши на значок Cache`

и в выпадающем меню выбрать "Портал управления системой". Главное окно Портала выглядит как:

В "Портале управления системой" классы и их описание можно просмотреть во вкладке "Классы":

Для просмотра описания класса следует выбрать ссылку "Документация". Описание класса на примере класса User.Organization:

Также в "Портале управления системой" можно посмотреть таблицы, которые имеются в БД. Для этого на Главной странице вместо вкладки "Классы" надо выбрать "SQL" и указать SQL схему (например, в области User):

Затем перейти на "Таблицы", чтобы увидеть те, которые присутствуют в БД. Названия таблиц совпадают с названиями соответствующих классов, знак точки заменяется на подчеркивание. Для хранения данных массивов создается отдельная таблица, название которой состоит из названия класса, в котором массив пределен, и названия массива.

Нажав на "OpenTable", можно просмотреть содержимое таблицы. Пример содержимого таблицы Worker:

Пример содержимого таблицы Organization:

Пример содержимого таблицы Manager:

Если в меню Главной страницы перейти на ссылку "Запросы", то можно просмотреть запросы для данной схемы. Например, просмотреть те запросы, которые относятся к п.2 и п.3: